gusucode.com > 耐品图片管理系统 标准版A > 耐品图片管理系统 标准版A/Search.asp

    <!--#include file="Head.asp"-->
<%
'===============================================================
' 著作权号：中国国家版权局著作权登记号2004SR07385
' 版权所有：深圳市耐品科技开发有限公司 www.naipin.com
' 联系电话：0755-26611119　81234844　81234845
' 联系手机：13316911914
' 联系邮箱：naipin@naipin.com
'===============================================================

With Netout
	.Load("Comm")
	if .GetCookie("View") <> "1" then
		.ShowErr(0)
		Response.End()
	End IF
	
	Dim rs,sql,CurrentPage,Show,strFileName,ClassID,Keyword,Recomm
	ClassID = .CheckNumeric(Request.QueryString("ClassID"))
	titleID = .CheckNumeric(Request.QueryString("titleID"))
	keyword = .ReplaceBadChar(.CheckStr(Request.QueryString("keyword"),""))
	
	ShowType = Trim(Request.QueryString("Type"))

	.InitText = .theCode(3)
End With
strFile = "Search.asp?Show="&Show&"&Type="&ShowType

Dim strField
If Not Purchase Is Nothing Then
	strField = Purchase.GetFieldName("b")
End If

Dim sqlPrefix,sqlString
sqlPrefix = "Select a.titleID,a.titleName,a.TitleUser,a.iClick,a.iCount,b.ID,b.ImageFile,b.ImageSize"&strField&" from Nt_title as a,Nt_ImgBook as b"
sqlString = sqlPrefix&" where b.titleID=a.titleID and b.Passed=1"&Netout.GetHideSql("b.")&" "

Select Case ShowType
Case "Recomm"
	Sql = sqlString & " and b.Recomm=1"
	strFile = strFile&"&Recomm=1"
Case "Essence"
	Sql = sqlPrefix & ",Nt_Score as c where b.titleID=a.titleId and b.Passed=1"&Netout.GetHideSql("b.")&" and c.ImageId=b.ID and c.Score>="&Config.Settings(15)&" and (c.Score/c.Count)>="&Config.Settings(16)
	strFile = strFile&"&Essence=1"
Case "IsHide"
	If Netout.GetCookie("ViewHide") = "0" Then
		Netout.ShowErr(9)
		Response.End()
	Else
		Sql = sqlPrefix & " where b.TitleId=a.TitleId and b.Passed=1 and b.IsHide=1"
	End If
Case Else
	IF titleID>0 Then
		Sql = sqlString & " and a.titleID="&titleID
		strFile = strFile&"&titleID="&titleID
	Else
		Sql = sqlString
		IF keyword<>"" then
			strFile = strFile&"&keyword="&keyword 
			Sql = Sql&" and (a.titleName like '%"&keyword&"%' or a.TitleUser like '%"&keyword&"%' or a.ManuName like '%"&keyword&"%' or b.Keyword like '%"&keyword&"%')"
			if ClassID>=1 then 
				Sql = Sql&" and a.ClassID="&ClassID
				strFile = strFile&"&ClassID="&ClassID
			End IF
		Else
			Dim ClassID2,titleName,titleName2,relation0,relation1,titleStyle
			Dim Desc,Desc2,relation2,relation3,Photoer,Num1,Num2,ComeUrl
			Dim Region,Photime,PhotimeB,PhotimeE
			
			With Request
				ClassID2   = Netout.CheckNumeric(.QueryString("ClassID2"))
				Photime    = Trim(.QueryString("Photime"))
				relation0  = Trim(.QueryString("relation0"))
				relation1  = Trim(.QueryString("relation1"))
				relation2  = Trim(.QueryString("relation2"))
				relation3  = Trim(.QueryString("relation3"))
				titleName  = Trim(.QueryString("titleName"))
				titleName2 = Trim(.QueryString("titleName2"))
				titleStyle = Trim(.QueryString("titleStyle"))
				Desc	   = Trim(.QueryString("Desc"))
				Desc2 	   = Trim(.QueryString("Desc2"))
				Photoer    = Trim(.QueryString("Photoer"))
				Num1 	   = Netout.CheckNumeric(Trim(.QueryString("Num1")))
				Num2 	   = Netout.CheckNumeric(Trim(.QueryString("Num2")))
				Region	   = Netout.CheckNumeric(.QueryString("Region"))
				PhotimeB   = Trim(.QueryString("PhotimeB"))
				PhotimeE   = Trim(.QueryString("PhotimeE"))
			End With
			
			If Photime = "" Then Photime = 7 Else Photime = Netout.CheckNumeric(Photime)
			If Not IsDate(PhotimeB) Then PhotimeB = ""
			If Not IsDate(PhotimeE) Then PhotimeE = ""
			
			IF ClassID = 0 And ClassID2 = 0 And titleName = "" And titleName2 = "" And Desc = "" And Desc2 = "" And Photoer = "" And Num1 = 0 And Num2 = 0 And Photime=7 And PhotimeB = "" And PhotimeE = "" Then
				Netout.ShowErr(17)
				Response.End()
			End IF
			
			IF relation0="" Then
				IF ClassID>=1 Then 
					Sql = Sql&" and a.ClassID="&ClassID
					strFile = strFile&"&ClassID="&ClassID
				End IF
			Else
				IF ClassID>0 or ClassID2>0 Then
					Sql = Sql&" and (a.ClassID="&ClassID&" "&relation0&" a.ClassID="&ClassID2&")"
					strFile = strFile&"&ClassID="&ClassID&"&ClassID2="&ClassID2&"&relation0="&relation0
				End IF
			End IF
			
			IF titleName<>"" Or titleName2<>"" Then
				strFile = strFile&"&titleName="&titleName&"&titleName2="&titleName2&"&relation1="&relation1
				IF titleStyle = "Have" Then
					Sql = Sql&" and (a.titleName like '%"&titleName&"%' "&relation1&" a.titleName like '%"&titleName2&"%')"
					strFile = strFile&"&titleStyle=Have"
				Else
					Sql = Sql&" and (a.titleName='"&titleName&"' "&relation1&" a.titleName='"&titleName2&"')"
					strFile = strFile&"&titleStyle=Must"
				End IF
			End IF
			
			IF Desc<>"" Or Desc2<>"" Then
				Sql = Sql&" and (a.titleDesc like '%"&Desc&"%' "&relation2&" a.titleDesc like '%"&Desc2&"%')"
				strFile = strFile&"&Desc="&Desc&"&Desc2="&Desc2&"&relation2="&relation2
			End IF
			
			IF Photoer<>"" Then 
				Sql = Sql&" and a.TitleUser='"&Photoer&"'"
				strFile = strFile&"&Photoer="&Photoer
			End IF
			
			If Region = 1 Then
				strFile = strFile&"&Region="&Region
				If PhotimeB<>"" Then
					Sql = Sql&" and DateDiff("&DateString(3)&","&DateString(7)&PhotimeB&DateString(7)&",b.AddTime)>=0"
				End If
				If PhotimeE<>"" Then
					Sql = Sql&" and DateDiff("&DateString(3)&","&DateString(7)&PhotimeE&DateString(7)&",b.AddTime)<=0"
				End If
			Else
				strFile = strFile&"&Photime="&Photime
				If Photime = 0 Then
					Sql = Sql&" and DateDiff("&DateString(3)&",b.AddTime,"&DateString(0)&")=0"
				ElseIf Photime>0 And Photime<=6 Then
					Sql = Sql&" and DateDiff("&DateString(3)&",b.AddTime,"&DateString(0)&")>="&Photime
				End If
			End If
			
			IF Num1>0 or Num2>0 Then
				If Len(Num1) >= 8 Then Num1 = CInt(Right(Num1,Len(Num1)-1))
				If Len(Num2) >= 8 Then Num2 = CInt(Right(Num2,Len(Num2)-1))
				
				Sql = Sql&" and (b.ID="&Num1&" "&relation3&" b.ID="&Num2&")"
				strFile = strFile&"&Num1="&Num1&"&Num2="&Num2&"&relation3="&relation3
			End IF			
		End IF
	End If
End Select
strFileName = strFile
Sql = Sql&" and a.iCount<>0 order by b.UpdateTime desc,b.ID desc"
%>
<!--#include file="CommShow.asp"-->